Excel VBA - conditional export to TXT (various text files) - vba

Question

I have from the past got help of creating a file to export values using this thread:
Export Excel range to TXT stop at empty cell.
This works but doesn´t do exactly what I want.
I have a list looking like this (with start from Column A):
What I want is that if Column C (Rename) has value Yes och Column E has value North it should do some thing and then export to txt.
It should depend of both Column C and E for what the outcome would become.
Example:
If Rename is Yes and Place is South --> Do this.
If Rename is No and Place is South --> Do another thing.
If Rename is Yes and Place is North --> It does another thing.
and so on...
Any sugestion how to begin?
Sub SaveToTXT()
Dim filename As String, lineText As String
Dim myrng As Range, i, j
filename = ThisWorkbook.path & "\textfile-" & Format(Now, "ddmmyy-hhmmss") & ".txt"
Open filename For Output As #1
Set myrng = Range("A:B")
For i = 1 To myrng.Rows.Count
For j = 1 To myrng.Columns.Count
If IsEmpty(myrng.Cells(i, j)) = True Then Close #1
If myrng(i, 3).Value = "No" And myrng(i, 5).Value = "North" Then 'do something, no replace'
If myrng(i, 3).Value = "Yes" And myrng(i, 5).Value = "North" Then 'do something, yes replace'
If myrng(i, 3).Value = "No" And myrng(i, 5).Value = "South" Then 'do something, no replace'
If myrng(i, 3).Value = "Yes" And myrng(i, 5).Value = "South" Then 'do something, yes replace'
If myrng(i, 3).Value = "No" And myrng(i, 5).Value = "West" Then 'do something, no replace'
If myrng(i, 3).Value = "Yes" And myrng(i, 5).Value = "West" Then 'do something, yes replace'
If myrng(i, 3).Value = "No" And myrng(i, 5).Value = "East" Then 'do something, no replace'
If myrng(i, 3).Value = "Yes" And myrng(i, 5).Value = "East" Then 'do something, yes replace'
If myrng(i, 3).Value = "No" And myrng(i, 5).Value = "NorthEast" Then 'do something, no replace'
If myrng(i, 3).Value = "Yes" And myrng(i, 5).Value = "NorthEast" Then 'do something, yes replace'
If myrng(i, 3).Value = "No" And myrng(i, 5).Value = "SouthEast" Then 'do something, no replace'
If myrng(i, 3).Value = "Yes" And myrng(i, 5).Value = "SouthEast" Then 'do something, yes replace'
Exit Sub
End If
lineText = IIf(j = 1, "", lineText & " ") & myrng.Cells(i, j)
Next j
Print #1, lineText
Next i
Close #1
End Sub
Edit/Addendum (cf. user comment): "What I want is that all that have the same match will be added to the same txt.file.
' I can only have a total of 12 files but all shouldn´t be created if the IF THEN isn´t a match.
' The txt-file should also have different names."

Answer 1

Approach via arrays and VBA Filter function
Here you find a tested approach that uses
a fully qualified reference to identify your current data region
constants to make code more readable
Arrays to structure data and make code faster (looping through a range is always slow)
helper functions to get one integer code based on several string inputs (Yes|No, cardinal direction)
instead of as much as 12 If conditions
the VBA Filter function to condense array data based on a search code and allow a subsequent loop over your case codes
the VBA Split function allowing to tokenize a term
requirements listed in your additional comment below:
Due to your comment:
"What I want is that all that have the same match will be added to the same txt.file.
I can only have a total of 12 files but all shouldn´t be created if the IF THEN isn´t a match.
The txt-file should also have different names."
Note See comments in code for further details.
Declaration head of your codemodule
Option Explicit ' Declaration head of your codemodule
Const NO = 0: Const YES = 1 ' Declare constants for ALL module procedures
Const North = 1: Const East = 3: Const South = 5: Const West = 7
Const NorthEast = 9: Const SouthEast = 11
Main procedure
Sub SaveToTXT()
' --------------------------
' 1. Declarations
' --------------------------
' a) Declare constants for used columns C (=3rd col) and E (=5th col)
Const RENAME = 3: Const PLACE = 5
' Declare variables
Dim filename As String, oldFile As String
Dim lineText As String, code As String, data
Dim i As Long ' row counter
Dim j As Long ' col counter
Dim n As Long ' last data row
Dim v As Variant ' receives 2-dimensional datafield array column A1:E{n}
Dim a() As Variant ' 1-dimensional array to hold string code & linetext
Dim fn As Integer ' free file number, INTEGER!
' b) Declare Worksheet object
Dim ws As Worksheet
' --------------------------
' 2. Get data
' --------------------------
' a) Define sheet name and set ws object to memory
Set ws = ThisWorkbook.Worksheets("SaveToText") ' << change to your sheet name :-)
' b) get last row of your sheet, assuming you have values in every row of column A!
n = ws.Range("A" & ws.Rows.Count).End(xlUp).Row
' c) create 2-dim datafield array from A:F .. plus 1 array column to hold conditions
' (becomes automatically 2-dimensional with 1-based indexation!)
v = ws.Range("A1:E" & n).Value ' A:E = 5 data columns
' d) create 1-dim array to hold lines and make it 1-based ("1 To ..")
ReDim a(1 To n)
' --------------------------
' 3. Prepare data for output
' --------------------------
For i = 2 To n ' loop through array rows (omitting 1 title row)
' a) create case codes 1-12 depending on YES|NO plus cardinal direction
code = chkRename(v(i, RENAME)) + chkPlace(v(i, PLACE))
' b) concatenate columns B to E, insert delimiter " " and omit column A
lineText = Split(Join(Application.Index(v, i, 0), " "), " ", 2)(1)
' c) write code & lineText to array a
a(i) = code & "|" & lineText
' Debug.Print "row: " & i, "code: " & code, lineText
Next i
' --------------------------
' 4. Write to 1-12 textfiles (North to SouthEast, marked with "(x)" in case of NO)
' --------------------------
On Error Resume Next: Close #fn
' Loop through codes 1-12 and filter array a(1-n) holding all code|lineText strings
For j = North To SouthEast + YES ' loop from code 1 to 12
' ---------------------
' 4.1 Filter array data
' ---------------------
data = Filter(a, j & "|") ' filter with search code j (1-12) & Delimiter!
' ---------------------
' 4.2 Check if there are any filtered data available
' ---------------------
If UBound(data) > -1 Then
' -------------------
' 4.3 Prepare writing
' -------------------
' a) get one of 12 filenames depending on individual case code
filename = getFileName(j) ' << helper function to build filename
If filename <> oldFile Then
' b) assign oldFile and close it
oldFile = filename
If oldFile <> "" Then Close #fn
' c) open new file
fn = FreeFile
Open filename For Output As #fn
End If
' ----------------
' 4.4 Write data
' ----------------
For i = LBound(data) To UBound(data)
' a) get linetext
lineText = Split(data(i), "|")(1) ' get second portion of term (=index 1)
' b) print lineText to file
Print #fn, lineText
' Debug.Print " code " & j & ": " & filename, lineText
Next i
End If ' end of condition data available for code j
Next j
On Error Resume Next: Close #fn
End Sub
Helper Functions used by Sub SaveToTXT
These helper functions generate an integer code depending on the Yes|No values in column RENAME and the Cardinal directions in column PLACE
Pay attention to the use of the defined constants.
(1) Function chkRename
Function chkRename(ByVal YesNo) As Integer
' Purpose: code string input "Yes" to 1, "No" to 0
chkRename = IIf(UCase(YesNo) = "YES", YES, NO)
End Function
(2) Function chkPlace
Function chkPlace(ByVal CardinalDirection) As Integer
' Purpose: code string argument to integer
' (steps of two to allow adding YES=1|NO=0 codes)
Dim a()
Dim i As Integer
' Keep this order, terms East or North have to be before NorthEast and SouthEast,
' as the function filters the search term CardinalDirction and
' returns the first finding with its 2nd portion, i.e. number 1-11, indicated by split index 1
' (otherwise "East" would be contained in SouthEast for example and found there first!)
a = Array("North 1", "East 3", "South 5", "West 7", "NorthEast 9", "SouthEast 11")
' return
chkPlace = Split(Filter(a, CardinalDirection)(0), " ")(1)
End Function
(3) Function getFileName
Function getFileName(ByVal code) As String
' Purpose: build file name depending on code for cardinal direction plus Yes|No code
' Example: North + YES is converted to "N" only, North + No to "N(x)"
' => e.g. path & "\textfile_310118_N(x).txt"
' Caveat: split string has to start with "Dummy,..."
Dim v As Variant
Dim i As Integer
v = Split("Dummy,N,N(x),E,E(x),S,S(x),W,W(x),NE,NE(x),SE,SE(x)", ",")
' return
getFileName = ThisWorkbook.Path & "\textfile_" & Format(Now, "ddmmyy") & "_" & v(val(code)) & ".txt"
End Function

Answer 2

inside the for loop you have in the previous answer you can have several IF THEN statements to achieve this
e.g. If myrng(i,3).value = "Yes" and myrng(i,5).value = "North" Then 'do something'
I hope that helps