Passing arrays in awk function - awk

Question

I want to write a function which accepts two arguments one is a constant values and another is an array. The function finds the index of the element in the arrays and returns it.I want to call this function with multiple arrays just as below what I have tried.
BEGIN{
a[1]=2;
a[2]=4;
a[3]=3;
b[1]=4;
b[2]=2;
b[3]=6;
c[1]=5;
c[2]=1;
c[3]=6;
arr[1]=a;
arr[2]=b;
arr[3]=c
}
function pos(val,ar[]) {
for (m=1;m<=length(ar);m++) { if (val == ar[m] )
return m;
else continue }
}
{for( k=1;k<=NF;k++) { for(l=1;l<=length(arr);l++) { print "pos=" pos($i,arr[l])} } }
but I am getting errors :
fatal: attempt to use array `a' in a scalar context
Looking at the code can anyone tell me how can I achieve what I am trying to achieve using awk. The challenge I have here is to assign and array as an element to another array as in arr[1]=a and passing the the array as a parameter by referencing it with its index as in pos($i,arr[l] . I dont know how to make these statements syntactically and functionally correct in awk .
the input is :
2 4 6
3 5 6
1 2 5
and in the out put the code should return the position of the value read from the file if it is present in any of the arrays defined
output:
1 1 3
6
2 1
in first line of output indexed of corresponding elements in the array a b and c have been returned respectively . 1 is index of 2 in a , 1 is index of 4 in b and 3 is index of 6 in c and so on for the upcoming lines in the input file.

Answer 1

I truly don't understand what it is you're trying to do (especially why an input of 2 produces the index from a but not the index from b while an input of 4 does the reverse) but to create a multi-dimensional array arr[][] from a[], b[], and c[] with GNU awk (the only awk that supports true multi-dimensional arrays) would be:
for (i in a) arr[1][i] = a[i]
for (i in b) arr[2][i] = b[i]
for (i in c) arr[3][i] = c[i]
not just arr[1] = a, etc. Note that you're storing a copy of the contents of a[] in arr[1][], not a reference to a[], so if a[] changes then arr[1][] won't. What you might want to do instead (again GNU awk only) is store the sub-array names in arr[] and then access them through the builtin variable SYMTAB (see the man page), e.g.:
$ cat tst.awk
BEGIN{
split("2 4 3",a)
split("4 2 6",b)
split("5 1 6",c)
arr[1] = "a"
arr[2] = "b"
arr[3] = "c"
prtArr(arr)
}
function prtArr(arr, i,subArrName) {
for (i=1; i in arr; i++) {
subArrName = arr[i]
printf "arr[%d] -> %s[] =\n", i, subArrName
prtSubArr(SYMTAB[subArrName])
}
}
function prtSubArr(subArr, j) {
for (j=1; j in subArr; j++) {
print "\t" subArr[j]
}
}
.
$ awk -f tst.awk
arr[1] -> a[] =
2
4
3
arr[2] -> b[] =
4
2
6
arr[3] -> c[] =
5
1
6
Now arr[] is no longer a multi-dimensional array, it's just an array of array name strings, and the contents of a[] are only stored in 1 place (in a[]) and just referenced from SYMTAB[] indexed by the contents of arr[N] rather than copied into arr[N][].