How to confirm my macro is working? - vba

Question

I am trying to get the below script working. I pasted into ThisOutlookSession and have created the appropriate path required (c:\mails). I have opened and closed outlook as well.
I have it pasted exactly as below, what am I missing? Is it supposed to show up when I call it using Alt+F8?
Thank you,
Private WithEvents Items As Outlook.Items
Private Sub Application_Startup()
Dim Ns As Outlook.NameSpace
Set Ns = Application.GetNamespace("MAPI")
Set Items = Ns.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub Items_ItemAdd(ByVal Item As Object)
If TypeOf Item Is Outlook.MailItem Then
SaveMailAsFile Item
End If
End Sub
Private Sub SaveMailAsFile(oMail As Outlook.MailItem)
Dim dtDate As Date
Dim sName As String
Dim sFile As String
Dim sExt As String
sPath = "c:\mails"
sExt = ".msg"
sName = oMail.Subject
ReplaceCharsForFileName sName, "_"
dtDate = oMail.ReceivedTime
sName = Format(dtDate, "yyyymmdd", vbUseSystemDayOfWeek, _
vbUseSystem) & Format(dtDate, "-hhnnss", _
vbUseSystemDayOfWeek, vbUseSystem) & "-" & sName & sExt
oMail.SaveAs sPath & sName, olSaveAsMsg
End Sub
Private Sub ReplaceCharsForFileName(sName As String, _
sChr As String _
)
sName = Replace(sName, "/", sChr)
sName = Replace(sName, "", sChr)
sName = Replace(sName, ":", sChr)
sName = Replace(sName, "?", sChr)
sName = Replace(sName, Chr(34), sChr)
sName = Replace(sName, "<", sChr)
sName = Replace(sName, ">", sChr)
sName = Replace(sName, "|", sChr)
End Sub

Answer 1

The code is not designed to be run manually- it's supposed to run automatically when you receive an email- It will not show up on under macro names ALT F8
There is nothing wrong using private sub if all the code are under the same module-
Now fix your folder Path- sPath = "c:\mails\" you are missing \

Answer 2

Code with one or more parameters, anything with something similar to (ByVal Item As Object), needs input.
There are various possibilities to test your code.
Sub Items_ItemAdd_Test
' with an open item
' a mailitem if you want to get to SaveMailAsFile
Items_ItemAdd ActiveInspector.CurrentItem
' or with anything selected
' a mailitem if you want to get to SaveMailAsFile
'Items_ItemAdd ActiveExplorer.Selection(1)
End Sub
Sub SaveMailAsFile_Test
' with an open MailItem
SaveMailAsFile ActiveInspector.CurrentItem
' or with a MailItem selected
'Items_ItemAdd ActiveExplorer.Selection(1)
End Sub
You may find a use for manually or programmatically moving or copying an item into the folder.