Copy parts of row if match across workbooks - vba

Question

I'm having two files to work with. One is the file to be updated, the other one contains new data.
Both files contain material numbers and information about this material (quantities etc), so i want all of the fresh values (which are part of the same row) to be copied into the right place of the row in the other file.
I managed to get everything working except a VLOOKUP (which should be needed..).
Anyone? :)
'################################################################################################
'################################################################################################
'######### fnopen(): Opens a FileDialog, allowing the user to choose the GLA File. #########
'######### Returns directory/filename of selected as String #########
'################################################################################################
'################################################################################################
Function fnopen() As String
Dim strFileToOpen As String
strFileToOpen = Application.GetOpenFilename _
(Title:="Please choose GLA501 to open")
'# Change name of FileDialog (is being displayed)
Workbooks.Open filename:=strFileToOpen
'# Open Workbook
fnopen = strFileToOpen
MsgBox fnopen & " 1"
MsgBox strFileToOpen & " 2"
End Function
'################################################################################################
'################################################################################################
'################################################################################################
'######### MakeRow(): Creates String of Cell out of row and String #########
'################################################################################################
Function MakeRow(rowno As Integer, col As String) As String
MakeRow = col & CStr(rowno)
End Function
'################################################################################################
'######### getmat(): Requires row no. and returns material no. #########
'################################################################################################
Function getmat(rowno As Integer, col As String) As String
getmat = Range(MakeRow(rowno, col)).Value
End Function
'################################################################################################
'################################################################################################
Function fcat(gla_path As String, gla_name As String, lastrow As Integer) As Integer
Dim srchRange As Range, found_in_location As Range, lookFor As Range
Dim rowno As Integer, counter As Integer
Dim col As String
rowno = 16
col = "F"
counter = 0
Dim book1 As Workbook
Dim book2 As Workbook
Set book1 = ThisWorkbook
Set book2 = Workbooks(gla_name)
Set lookFor = book2.Sheets(1).Cells(rowno, 6) ' value to find
Set srchRange = book1.Sheets(2).Range(MakeRow(rowno, col), MakeRow(lastrow, col)) 'source
Set found_in_location = srchRange.Columns(1).Find(What:=lookFor, LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=False)
If Not found_in_location Is Nothing Then
found_in_location.Offset(0, 85).Value = lookFor.Offset(0, 79)
Else
counter = counter + 1
End If
fcat = counter
End Function
'################################################################################################
'################################################################################################
Sub annualazy()
Dim gla_path As String, gla_name As String, col As String, rowno As Integer, counter As Integer, lastrow As Integer
MsgBox ("This VBA updates 'DC_Annual_Planning' by copying values from '4510_GLA501_DC'. Make sure to select the correct files!")
gla_path = fnopen()
gla_name = Right(gla_path, Len(gla_path) - InStrRev(gla_path, "\"))
rowno = 16
col = "F"
lastrow = Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).row
MsgBox lastrow
MsgBox gla_name
MsgBox getmat(rowno, col)
MsgBox fcat(gla_path, gla_name, lastrow)
End Sub

Answer 1

Could it be that the value you search for simply isn't found, and that is what creates your problem?
Anyway, when working in VBA, I prefer using Find over VLOOKUP. Without reviewing the rest of your code, and assuming the line you have problems with is lookFor.Offset(0, 79).Value = Application.VLookup(lookFor, srchRange, 2, False), you can replace it with something like:
Dim found_in_location As Range
Set found_in_location = srchRange.Columns(1).Find(What:=lookFor, LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=False)
If Not found_in_location Is Nothing Then
lookFor.Offset(0, 79).Value = found_in_location.Offset(0, 2)
Else
' What will you do if the value is not found?
End If
While it takes up a bit more space than the VLOOKUP-line, it is both easier to read and to debug.