strange behavior when concatenating strings in VBA - vba

Question

Here's what I'm trying to do.
We occasionally get emails that has the following info:
Name: In the subject line between ( and -
DoB: In the e-mail Body:
date for receving e-mail: In the mail item itself.
I can get the name and date easily enough, but the DoB is behaving strange when I try to add it to the file name, it'll usually discard the name I've extracted.
This is the code I'm using:
Sub SaveAsPDF(MyMail As MailItem)
' ### Requires reference to Microsoft Scripting Runtime ###
' ### Requires reference to Microsoft Word Object Library ###
' --- In VBE click TOOLS > REFERENCES and check the boxes for both of the above ---
Dim fso As FileSystemObject
Dim strSubject As String
Dim strSaveName As String
Dim blnOverwrite As Boolean
Dim strFolderPath As String
Dim sendEmailAddr As String
Dim clientName As String
Dim openPos1 As Integer
Dim closePos1 As Integer
Dim openPos2 As Integer
Dim closePos2 As Integer
Dim senderName As String
Dim looper As Integer
Dim plooper As Integer
Dim strID As String
Dim olNS As Outlook.NameSpace
Dim oMail As Outlook.MailItem
Dim bDay As String
strID = MyMail.EntryID
Set olNS = Application.GetNamespace("MAPI")
Set oMail = olNS.GetItemFromID(strID)
emailSubject = CleanFileName(oMail.Subject)
' ### Get username portion of sender email address ###
sendEmailAddr = oMail.SenderEmailAddress
senderName = Left(sendEmailAddr, InStr(sendEmailAddr, "#") - 1)
' ### Get Client birthday ###
openPos1 = InStr(oMail.Body, "DOB:")
closePos1 = InStr(oMail.Body, "TLF:")
bDay = Mid(oMail.Body, openPos1 + 12, closePos1 - openPos1 - 12)
' ### USER OPTIONS ###
blnOverwrite = False ' False = don't overwrite, True = do overwrite
' ### Path to save directory ###
bPath = "C:\Email test\"
' ### Create Directory if it doesnt exist ###
If Dir(bPath, vbDirectory) = vbNullString Then
MkDir bPath
End If
' ### Get Email subject & set name to be saved as ###
saveName = clientName & " " & Format(oMail.ReceivedTime, "dd-mm-yyyy") & ".mht"
Set fso = CreateObject("Scripting.FileSystemObject")
' ### Get the client name from the email subject ###
openPos2 = InStr(emailSubject, "(")
closePos2 = InStr(emailSubject, "-")
clientName = Mid(emailSubject, openPos2 + 1, closePos2 - openPos2 - 1)
' ### Increment filename if it already exists ###
If blnOverwrite = False Then
looper = 0
Do While fso.FileExists(bPath & saveName)
looper = looper + 1
saveName = clientName & " " & Format(oMail.ReceivedTime, "dd-mm-yyyy") & " " & looper & ".mht"
Loop
Else
End If
' ### Save .mht file to create pdf from Word ###
oMail.SaveAs bPath & saveName, olMHTML
pdfSave = bPath & clientName & " " & Format(oMail.ReceivedTime, "dd-mm-yyyy") & ".pdf"
If fso.FileExists(pdfSave) Then
plooper = 0
Do While fso.FileExists(pdfSave)
plooper = plooper + 1
pdfSave = bPath & clientName & " " & Format(oMail.ReceivedTime, "dd-mm-yyyy") & " " & plooper & ".pdf"
Loop
Else
End If
' ### Open Word to convert .mht file to PDF ###
Dim wrdApp As Word.Application
Dim wrdDoc As Word.Document
Set wrdApp = CreateObject("Word.Application")
' ### Open .mht file we just saved and export as PDF ###
Set wrdDoc = wrdApp.Documents.Open(FileName:=bPath & saveName, Visible:=True)
wrdApp.ActiveDocument.ExportAsFixedFormat OutputFileName:= _
pdfSave, ExportFormat:= _
wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:= _
wdExportOptimizeForPrint, Range:=wdExportAllDocument, From:=0, To:=0, _
Item:=wdExportDocumentContent, IncludeDocProps:=True, KeepIRM:=True, _
CreateBookmarks:=wdExportCreateNoBookmarks, DocStructureTags:=True, _
BitmapMissingFonts:=True, UseISO19005_1:=False
wrdDoc.Close
wrdApp.Quit
' ### Delete .mht file ###
Kill bPath & saveName
Set oMail = Nothing
Set olNS = Nothing
Set fso = Nothing
End Sub
This will save a PDF file with the name like "Marty Smith 04-06-2020" however if I add the String "bDay" into the file name, it'll disregard the name, and the DOB, and only add the date, but Word will fail to save and hang in a background process.
' ### Save .mht file to create pdf from Word ###
oMail.SaveAs bPath & saveName, olMHTML
pdfSave = bPath & clientName & " " & bDay & " " & Format(oMail.ReceivedTime, "dd-mm-yyyy") & ".pdf"
If fso.FileExists(pdfSave) Then
plooper = 0
Do While fso.FileExists(pdfSave)
plooper = plooper + 1
pdfSave = bPath & clientName & " " & bDay & " " & Format(oMail.ReceivedTime, "dd-mm-yyyy") & " " & plooper & ".pdf"
Loop
Else
End If

Answer 1

My closing position for InStr included 2 newlines from the Email body, that wasn't apparent to me when I was showing the output via Msgbox.
Debug.Print bDay helped me to see what the issue was and adjusting the closePos variable to remove the newlines.